NWN:EE bat files

Hints and Guidelines, How To's on Registration, Activation, NWN, etc.

Moderators: Forum Moderators, Active DMs

Morderon
Technical Lead
Technical Lead
Posts: 1271
Joined: Mon Sep 08, 2014 2:24 am

NWN:EE bat files

Post by Morderon » Tue Mar 27, 2018 10:39 pm

Below you'll find two bat file contents.

Copy & Paste them into notepad and file save as (anynameyouwant).bat

Note: The ip address and port for NWN:EE C&P and Surface are assumed, they may end up being different when they're actually live.

Both feature a log rotator. They do not enable logging on your behalf, for that you must do so yourself.

Towards the top of the .bat file each feature lines similar to:

Code: Select all

::Your NWNL:EE log directory location on the next line.
set EEDocDir="D:\Documents\Neverwinter Nights"
::Your EE nwmain.exe install directory on the next line
set EEInstallDir="E:\Program Files\Steam\steamapps\common\Neverwinter Nights\bin\win32" 
::The location of your logs folder of your 1.69 install on the next line
set NWN169Dir="E:\GalaxyClient\Games\NWN Diamond"
:: Your 1.69 nwmain.exe install directory on the next line, only modify if it's different location from your logs folder 
set NWN169GameDir=%NWN169Dir% 
Read the comments to know how to modify the lines below them. (Comments are the lines proceeded with ::)

Use bat file 1 if you want to enter your player name each and every time you play the game or only ever have 1 player name.

Use bat file 2 if you want to remember your last login with the option to log in with another one.

Bat file 2 requires additional set up. You must log into NWN:EE, log into any server (Arelith counts as any server) and when asked for a player name, type one in and check mark set as default. Hit OK. You are now ready to use bat file 2. If you're paranoid you can back up your nwnplayer.ini.

Bat file 2 assumes your log directory and nwnplayer.ini are in the same folder.

Bat file 1:

Code: Select all

@echo off
::Your NWNL:EE log directory location on the next line.
set EEDocDir="D:\Documents\Neverwinter Nights"
::Your EE nwmain.exe install directory on the next line
set EEInstallDir="E:\Program Files\Steam\steamapps\common\Neverwinter Nights\bin\win32" 
::The location of your logs folder of your 1.69 install on the next line
set NWN169Dir="E:\GalaxyClient\Games\NWN Diamond"
:: Your 1.69 nwmain.exe install directory on the next line, only modify if it's different location from your logs folder 
set NWN169GameDir=%NWN169Dir% 
echo Select a Server
echo 1. NWN: EE Distant Shores
echo 2. NWN: EE Cities and Planes
echo 3. NWN: EE Surface
echo 4. NWN: 1.69 PGCC Arena
echo 5. NWN: 1.69 FL
set /p servervar= Server Number:
if %servervar% lss 4 (
  set logdir=%EEDocDir%
  cd /D %EEInstallDir%
  if %servervar% == 1 start /wait nwmain.exe +connect game.arelith.com:5121
  if %servervar% == 2 start /wait nwmain.exe +connect game.arelith.com:5122
  if %servervar% == 3 start /wait nwmain.exe +connect game.arelith.com:5123
)


if %servervar% gtr 3 (
  set logdir=%NWN169Dir%
  cd /D %NWN169GameDir%

  if %servervar% == 4 start /wait nwmain.exe +connect arena.arelith.com:5121
  if %servervar% == 5 start /wait nwmain.exe +connect fl.arelith.com:5121
)

for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"
set TODAY=%YYYY%-%MM%-%DD%
set NOW=%HH%-%Min%-%Sec%
move %logdir%\logs\nwclientLog1.txt %logdir%\logs\log-%TODAY%-%NOW%.txt
Bat file 2:

Code: Select all

@setlocal enableextensions enabledelayedexpansion
@echo off
::Your NWNL:EE docoument directory on the next line, the location of your logs directory and nwnplayer.ini
set EEDocDir="D:\Documents\Neverwinter Nights"
::Your EE nwmain.exe install directory on the next line
set EEInstallDir="E:\Program Files\Steam\steamapps\common\Neverwinter Nights\bin\win32" 
::The location of your logs folder of your 1.69 install on the next line
set NWN169Dir="E:\GalaxyClient\Games\NWN Diamond"
:: Your 1.69 nwmain.exe install directory on the next line, only modify if it's different location from your logs folder 
set NWN169GameDir=%NWN169Dir% 
echo Select a Server
echo 1. NWN: EE Distant Shores
echo 2. NWN: EE Cities and Planes
echo 3. NWN: EE Surface
echo 4. NWN: 1.69 PGCC Arena
echo 5. NWN: 1.69 FL
set /p servervar= Server Number:
if %servervar% lss 4 (
  set logdir=%EEDocDir%
  cd /D !logdir!
  set file=nwnplayer.ini
  set area=[Profile]
  set key=Player Name
  set currarea=
  for /f "usebackq delims=" %%a in ("!file!") do (
    set ln=%%a
    if "x!ln:~0,1!"=="x[" (
        set currarea=!ln!
    ) else (
        for /f "tokens=1,2 delims==" %%b in ("!ln!") do (
            set currkey=%%b
            set currval=%%c
            if "x!area!"=="x!currarea!" if "x!key!"=="x!currkey!" (
	        set curlogin=!currval!
                echo Current login: !currval!
            )
         )
    )
  )
  set /p id= "New Login (Hit Enter to leave unchanged):"
  
  if NOT [!id!] == [] (
   
   Set _OldLine=!key!=!curlogin!
   Set _NewLine=!key!=!id!
  
   :: End of Search parameters
   Call :_Parse "!file!"
   Set _Len=0
   Set _Str=!_OldLine!
   Set _Str=!_Str:"=.!987654321
   
   :_Loop
   If NOT "!_Str:~18!"=="" Set _Str=!_Str:~9!& Set /A _Len+=9& Goto _Loop
   Set _Num=!_Str:~9,1!
   Set /A _Len=_Len+_Num
   PushD !_FilePath!
   If Exist !_FileName!.new Del !_FileName!.new
   If Exist !_FileName!.old Del !_FileName!.old
   Set _LineNo=0
   For /F "Tokens=* Eol=" %%I In (!_FileName!!_FileExt!) Do (
   Set _tmp=%%I
   Set /A _LineNo+=1
   If /I "!_tmp:~0,%_Len%!"=="!_OldLine!" (
   >>!_FileName!.new Echo !_NewLine!
   ) Else (
   If !_LineNo! GTR 1 If "!_tmp:~0,1!"=="[" Echo.>>!_FileName!.new
   
	
   >>!_FileName!.new Echo %%I

   ))
   Ren !_FileName!!_FileExt! !_FileName!.old
   Ren !_FileName!.new !_FileName!.ini
   ::PopD
   ::Goto :EOF   
   
  )
  
  
  
  cd /D %EEInstallDir%
  if %servervar% == 1 start /wait nwmain.exe +connect game.arelith.com:5121
  if %servervar% == 2 start /wait nwmain.exe +connect game.arelith.com:5122
  if %servervar% == 3 start /wait nwmain.exe +connect game.arelith.com:5123
)
::if %servervar% == 2 start /wait nwmain.exe +connect game.arelith.com:5123

if %servervar% gtr 3 (
  set logdir=%NWN169Dir%
  cd /D %NWN169GameDir%

  if %servervar% == 4 start /wait nwmain.exe +connect arena.arelith.com:5121
  if %servervar% == 5 start /wait nwmain.exe +connect fl.arelith.com:5121
)

for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"
set TODAY=%YYYY%-%MM%-%DD%
set NOW=%HH%-%Min%-%Sec%
move %logdir%\logs\nwclientLog1.txt %logdir%\logs\log-%TODAY%-%NOW%.txt
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Subroutines
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
   :_Parse
     Set _FilePath=%~dp1
     Set _FileName=%~n1
     Set _FileExt=%~x1
     Goto :EOF 
endlocal
Incorrect dates/no dates on log:

First check if your system time is correct, if it is continue reading.

Was an issue for one known case for a Windows 8.1 user.

To fix change set TODAY=%year%-%month%-%day%

to
set TODAY=%date%

Old way to get date/time in case you don't like military time:

Code: Select all

for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set year=%%c
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set month=%%a
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set day=%%b
set TODAY=%year%-%month%-%day%
for /f "tokens=1 delims=: " %%h in ('time /T') do set hour=%%h
for /f "tokens=2 delims=: " %%m in ('time /T') do set minutes=%%m
for /f "tokens=3 delims=: " %%a in ('time /T') do set ampm=%%a
set NOW=%hour%-%minutes%-%ampm%
move %logdir%\logs\nwclientLog1.txt %logdir%\logs\log-%TODAY%-%NOW%.txt
Last edited by Morderon on Fri Apr 13, 2018 11:23 pm, edited 4 times in total.

User avatar
Commissar
Posts: 288
Joined: Wed Nov 25, 2015 12:48 pm
Location: Australia

Re: NWN:EE bat files

Post by Commissar » Thu Mar 29, 2018 3:54 am

These are wonderful .bat files. Thank you! This deserves a sticky.
May you live in interesting times.
Manticore, on Sun Elves wrote:Yeah, I'm pretty sure the racism is like a mating ritual or something. Like plumes on birds.

User avatar
Maladus
Posts: 808
Joined: Sun Oct 18, 2015 4:43 am

Re: NWN:EE bat files

Post by Maladus » Fri Mar 30, 2018 3:56 am

So if I only want to use this for EE I can delete the lines referring to anything 1.69 right?

User avatar
Cuchilla
Arelith Supporter
Arelith Supporter
Posts: 567
Joined: Mon Sep 08, 2014 2:22 am
Location: Denmark

Re: NWN:EE bat files

Post by Cuchilla » Fri Mar 30, 2018 6:11 am

Had had to see up the phenomenon log ration (Wikipedia) to get anything of what this is about.

From what I read, I got this: I need one of those two files if I want to auto-archive my logfiles. If I don't what to do that, I don't need to do this.

Is that correctly understood?

Aloise "Lois", Biarray "Ray", Uniethrade. INACTIVE: Ivory Bushdiggger DEAD: Cuchilla. Beliat, Clyasy. Cristyn. Fadriatta. Fraya Stensamler (Chief Librarian). Goirin. Greensleeves. Gwydynya. Hilda. Kaxandra. Trista. Willisa.


User avatar
Maladus
Posts: 808
Joined: Sun Oct 18, 2015 4:43 am

Re: NWN:EE bat files

Post by Maladus » Fri Mar 30, 2018 7:16 am

You need one of these files if you installed NWN:EE on Steam and don't want it to auto-update. Morderon or someone else will have to confirm the bit about logs, but it seems like these do not enable logging.

User avatar
Look to Windward
Posts: 40
Joined: Tue Nov 28, 2017 9:38 am

Re: NWN:EE bat files

Post by Look to Windward » Fri Mar 30, 2018 10:53 am

Cuchilla wrote:
Fri Mar 30, 2018 6:11 am
Is that correctly understood?
Yep. These files will auto-rotate your logs. This will do nothing if you haven't enabled logging in your Nwnplayer.ini. They'll also allow you to connect without going through steam or the beamdog launcher.

As far as I can tell the 1.69 related code is to allow you to connect to the current PGCC and Fixed Level, which both operate using 1.69.

If you're not particularly interested in doing those things, then you don't need these.
It's crooked, but it's the only game in town.

Morderon
Technical Lead
Technical Lead
Posts: 1271
Joined: Mon Sep 08, 2014 2:24 am

Re: NWN:EE bat files

Post by Morderon » Fri Mar 30, 2018 11:37 am

Maladus wrote:
Fri Mar 30, 2018 3:56 am
So if I only want to use this for EE I can delete the lines referring to anything 1.69 right?
Yup don't need those lines if you don't need them.

Features of these bat files as noted above are:
Direct connecting to all things Arelith. This has the side effect of bypassing steam so you don't auto-update.
Log rotation (has to be enabled first)
Additionally bat file 2 has a player name switcher, which remembers your last log in and gives you an option to change it without opening your nwnplayer.ini

User avatar
Maladus
Posts: 808
Joined: Sun Oct 18, 2015 4:43 am

Re: NWN:EE bat files

Post by Maladus » Sat Mar 31, 2018 5:46 am

It looks like it's not accepting any overrides that you subscribe to in the workshop. I have a weapon model override that did not appear when using the batch file but did when I launched it through Steam.

User avatar
Maladus
Posts: 808
Joined: Sun Oct 18, 2015 4:43 am

Re: NWN:EE bat files

Post by Maladus » Sat Mar 31, 2018 5:47 am

It looks like it's not accepting any overrides that you subscribe to in the workshop. I have a weapon model override that did not appear when using the batch file but did when I launched it through Steam.

User avatar
cptcuddlepants
Posts: 424
Joined: Fri Dec 02, 2016 5:52 pm
Location: ruining the server

Re: NWN:EE bat files

Post by cptcuddlepants » Sat Mar 31, 2018 5:47 am

If you download something from the Steam Workshop, it will not activate or show up ingame unless you launch NWN through Steam.
When the going gets tough, the tough hide under the table.

Get Jad's portrait here!

User avatar
Maladus
Posts: 808
Joined: Sun Oct 18, 2015 4:43 am

Re: NWN:EE bat files

Post by Maladus » Sat Mar 31, 2018 7:22 am

Is it possible to fix that with the batch files?

Morderon
Technical Lead
Technical Lead
Posts: 1271
Joined: Mon Sep 08, 2014 2:24 am

Re: NWN:EE bat files

Post by Morderon » Sat Mar 31, 2018 11:57 am

Maybe. But it bypassing steam is a bit of the whole point so it doesnt auto update. You can find non steam versions of those overrides often on the vault or find out where steam workshop is storing them and place them in your override folder.

Morderon
Technical Lead
Technical Lead
Posts: 1271
Joined: Mon Sep 08, 2014 2:24 am

Re: NWN:EE bat files

Post by Morderon » Sat Mar 31, 2018 12:26 pm

If you really want to launch the game through steam and potentially update the game before the server is updated.

You can change one of these lines, or add a new one: start /wait nwmain.exe +connect game.arelith.com:5121 to

start /wait steam://rungameid/704450

Then in steam right click nwn ee, properties, set launch options, and add +connect game.arelith.com:5121. It seems you'll only ever able to have one steam direct connect at a time.

User avatar
triaddraykin
Arelith Silver Supporter
Arelith Silver Supporter
Posts: 735
Joined: Mon Sep 08, 2014 2:32 am

Re: NWN:EE bat files

Post by triaddraykin » Thu Apr 12, 2018 5:48 am

This makes absolutely no sense. The syntax doesn't match at all.

log--12-18-01-38-.txt comes from

Code: Select all

for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set year=%%c
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set month=%%a
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set day=%%b
set TODAY=%year%-%month%-%day%
for /f "tokens=1 delims=: " %%h in ('time /T') do set hour=%%h
for /f "tokens=2 delims=: " %%m in ('time /T') do set minutes=%%m
for /f "tokens=3 delims=: " %%a in ('time /T') do set ampm=%%a
set NOW=%hour%-%minutes%-%ampm%
move %logdir%\logs\nwclientLog1.txt %logdir%\logs\log-%TODAY%-%NOW%.txt
And the time was April 12, 2018 at 1:38 AM

Time's set right, by timeanddate.com. Changing the Set TODAY to year just makes it not work at all. Running as administrator doesn't matter.

Unless I'm insane, it's somehow getting the syntax of month-day-year from year-month-day. I tried tinkering with the %%a to match the ending letters, like it does at the time, but I ended up with log-12-12-12-01-26-.txt instead. At least it has a month entry now?
Alia: The uncanny knack of Angela Amana to make the otherwise perpetually well-mannered girl lose her temper and be HORRIBLY ASHAMED afterwards.

Who on the Team to PM and When
Public Tower Discord
Tower Library
Scroll, Wand, & Potion Costs

DM Apollo
Posts: 422
Joined: Sat Jan 20, 2018 7:34 pm

Re: NWN:EE bat files

Post by DM Apollo » Thu Apr 12, 2018 11:24 am

The issue is that %date% can vary.

echo %date% on my system returns '2018-04-12'
For Mord's system that this script is based off of %date% returns 'Sat 04/12/2018'

So see what your %date% returns and parse it differently. For those where %date% matches my system you can change

Code: Select all

for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set year=%%c
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set month=%%a
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set day=%%b
set TODAY=%year%-%month%-%day%
to

Code: Select all

set TODAY=%date%
If you post what your echo %date% and echo %time% return we can try to find an updated script for you as well triaddraykin.

User avatar
triaddraykin
Arelith Silver Supporter
Arelith Silver Supporter
Posts: 735
Joined: Mon Sep 08, 2014 2:32 am

Re: NWN:EE bat files

Post by triaddraykin » Fri Apr 13, 2018 5:03 am

C:\Users\Triaddraykin>echo %date%
04/13/18

C:\Users\Triaddraykin>echo %time%
1:03:38.82
Alia: The uncanny knack of Angela Amana to make the otherwise perpetually well-mannered girl lose her temper and be HORRIBLY ASHAMED afterwards.

Who on the Team to PM and When
Public Tower Discord
Tower Library
Scroll, Wand, & Potion Costs

Morderon
Technical Lead
Technical Lead
Posts: 1271
Joined: Mon Sep 08, 2014 2:24 am

Re: NWN:EE bat files

Post by Morderon » Fri Apr 13, 2018 4:00 pm

Code: Select all

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set datestamp=%YYYY%-%MM%-%DD% & set timestamp=%HH%:%Min%:%Sec%
set fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%
echo datestamp: %datestamp%
echo timestamp: %timestamp%
echo fullstamp: %fullstamp%
pause
If triaddraykin and apollo can try that one and let me know the output. If it's uniform amongst all of us I'll replace the current method with it.

The one currently within the bats is apparently region dependent or something.

My output:

Code: Select all

datestamp: 2018-04-13
timestamp: 11:54:16
fullstamp: 2018-04-13_11-54-16

User avatar
triaddraykin
Arelith Silver Supporter
Arelith Silver Supporter
Posts: 735
Joined: Mon Sep 08, 2014 2:32 am

Re: NWN:EE bat files

Post by triaddraykin » Fri Apr 13, 2018 9:30 pm

I get

Code: Select all

datestamp: 2018-04-13
timestamp: 17:30:03
fullstamp: 2018-04-13_17-30-03
Alia: The uncanny knack of Angela Amana to make the otherwise perpetually well-mannered girl lose her temper and be HORRIBLY ASHAMED afterwards.

Who on the Team to PM and When
Public Tower Discord
Tower Library
Scroll, Wand, & Potion Costs

Morderon
Technical Lead
Technical Lead
Posts: 1271
Joined: Mon Sep 08, 2014 2:24 am

Re: NWN:EE bat files

Post by Morderon » Fri Apr 13, 2018 11:25 pm

Updated the bat files above, hopefully they work for all oses/regions now.

It also now uses military time and I included the second the log file was created in the name.

User avatar
triaddraykin
Arelith Silver Supporter
Arelith Silver Supporter
Posts: 735
Joined: Mon Sep 08, 2014 2:32 am

Re: NWN:EE bat files

Post by triaddraykin » Sat Apr 14, 2018 12:06 am

Code: Select all

log-2018-04-13-20-05-51.txt
is the result! You are the man, Morderon!
Alia: The uncanny knack of Angela Amana to make the otherwise perpetually well-mannered girl lose her temper and be HORRIBLY ASHAMED afterwards.

Who on the Team to PM and When
Public Tower Discord
Tower Library
Scroll, Wand, & Potion Costs

User avatar
Rigela
Posts: 211
Joined: Wed Jan 31, 2018 10:28 pm

Re: NWN:EE bat files

Post by Rigela » Fri Jun 01, 2018 9:58 pm

This doesn't seem to work for me anymore with the recent update. Get "could not translate address" regardless of what I do. I can log on normally though, but not sure if I am meant to change anything with the update as does make it much more convenient to log in with.
Isabella Isherwood - Priestess of Selune
Piper Barley - Joybringer of Lliira

Morderon
Technical Lead
Technical Lead
Posts: 1271
Joined: Mon Sep 08, 2014 2:24 am

Re: NWN:EE bat files

Post by Morderon » Fri Jun 01, 2018 10:26 pm

I don't think the problem is on the bat files end.

With any shortcut i make (bat file or not) the direct connect link fails for arelith servers and non-arelith servers.

User avatar
Rigela
Posts: 211
Joined: Wed Jan 31, 2018 10:28 pm

Re: NWN:EE bat files

Post by Rigela » Fri Jun 01, 2018 10:41 pm

Ah, makes sense would be on the other end then.

Guess is just using the old way for now then.
Isabella Isherwood - Priestess of Selune
Piper Barley - Joybringer of Lliira

User avatar
triaddraykin
Arelith Silver Supporter
Arelith Silver Supporter
Posts: 735
Joined: Mon Sep 08, 2014 2:32 am

Re: NWN:EE bat files

Post by triaddraykin » Sat Jun 02, 2018 8:12 pm

Perhaps make a modified version that doesn't choose a server, but still creates the log?

EDIT: If I try to direct connect a second time, it always goes through, on both servers. Don't know it that helps.
Alia: The uncanny knack of Angela Amana to make the otherwise perpetually well-mannered girl lose her temper and be HORRIBLY ASHAMED afterwards.

Who on the Team to PM and When
Public Tower Discord
Tower Library
Scroll, Wand, & Potion Costs

User avatar
triaddraykin
Arelith Silver Supporter
Arelith Silver Supporter
Posts: 735
Joined: Mon Sep 08, 2014 2:32 am

Re: NWN:EE bat files

Post by triaddraykin » Mon Jun 04, 2018 10:17 pm

I went and modified my own.

Code: Select all

@setlocal enableextensions enabledelayedexpansion
@echo off
::Your NWNL:EE docoument directory on the next line, the location of your logs directory and nwnplayer.ini
set EEDocDir="C:\Users\Triaddraykin\Documents\Neverwinter Nights"
::Your EE nwmain.exe install directory on the next line
set EEInstallDir="D:\SteamLibrary\steamapps\common\Neverwinter Nights\bin\win32" 
::The location of your logs folder of your 1.69 install on the next line
set NWN169Dir="C:\Users\Triaddraykin\Documents\Neverwinter Nights"
:: Your 1.69 nwmain.exe install directory on the next line, only modify if it's different location from your logs folder 
set NWN169GameDir=%NWN169Dir% 
echo Select a Server
echo 1. NWN: EE Distant Shores
echo 2. NWN: EE Cities and Planes
echo 3. NWN: EE Surface
echo 4. NWN: Main
set /p servervar= Server Number:
if %servervar% lss 5 (
  set logdir=%EEDocDir%
  cd /D %EEInstallDir%
  if %servervar% == 1 start /wait nwmain.exe +connect game.arelith.com:5121
  if %servervar% == 2 start /wait nwmain.exe +connect game.arelith.com:5122
  if %servervar% == 3 start /wait nwmain.exe +connect game.arelith.com:5123
  if %servervar% == 4 start /wait nwmain.exe
)

for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"
set TODAY=%YYYY%-%MM%-%DD%
set NOW=%HH%-%Min%-%Sec%
move %logdir%\logs\nwclientLog1.txt %logdir%\logs\log-%TODAY%-%NOW%.txt
A display of the relevant differences: https://imgur.com/zg93oPE
Alia: The uncanny knack of Angela Amana to make the otherwise perpetually well-mannered girl lose her temper and be HORRIBLY ASHAMED afterwards.

Who on the Team to PM and When
Public Tower Discord
Tower Library
Scroll, Wand, & Potion Costs

Post Reply